- (a)
- The wavefunctions and energies of the unperturbed problem are
> psi0 := (n,x) -> sqrt(2/L)*sin(n*Pi*x/L);
> E0 := n -> n^2*h^2/(8*m*L^2);
The values of the parameters are (in SI units)
> L := 1e-9;
> h := 6.6261e-34;
> m := 9.1094e-31;
> V0 := 2e-20;
(V0 is the constant potential in the left side of the box.)
The energy correction is
> E1 := n -> V0*int(psi0(n,x)^2,x=0..L/3);
The total energy is therefore
> En := n -> E0(n) + E1(n);
You can now evaluate the total and zero-order energies (using Maple)
and plot them
(by hand is easiest).
> E0(1); En(1);
> E0(2); En(2);
> E0(3); En(3);
- (b)
- Transitions between n=1 and n=2 involve photons of
energy E2-E1. For the particle in a box, this
difference is
> E0(2)-E0(1);
For the bumpy box problem, we have
> En(2)-En(1);
The latter energy difference is larger so the wavelength (which is
inversely proportional to photon energy) is smaller.
- (c)
- We first need to compute the coefficients. These are (in general)
> c := (n,k) -> V0*int(psi0(k,x)*psi0(n,x),x=0..L/3)/(E0(n)-E0(k));
Here we want n=1 (ground state), so the relevant coefficients
are
> c(1,2);
-.03050375384
> c(1,3);
-.008579180767
> c(1,4);
-.001220150156
> c(1,5);
.0009532423062
> c(1,6);
.0008964368480
> c(1,7);
.0002383105776
The only sensible place to cut off the series (satisfying our factor
of 5 criterion) is after c1,3.
> psi_u := x -> psi0(1,x) + c(1,2)*psi0(2,x) + c(1,3)*psi0(3,x);
Let us now normalize this wavefunction:
> N1 := 1/sqrt(int(psi_u(x)^2,x=0..L));
> psi_1 := x -> N1*psi_u(x);
- (d)
> plot([psi0(1,x),psi_1(x)],x=0..L,color=[red,blue]);
The probability density is enhanced to the right where the potential
energy is zero. This makes perfect sense.
- (e)
- The average kinetic energy is computed by
> hbar := h/(2*Pi);
> evalf(-hbar^2/(2*m)*int(psi_1(x)*diff(psi_1(x),x$2),x=0..L));
The average potential energy is
> V0*int(psi_1(x)^2,x=0..L/3);
The sum of these two quantities is
> %+%%;
The energy computed by perturbation theory is
> En(1);
The difference between these quantities is small.
- Bonus:
- The difference is probably due
to the truncation of the infinite series for the wavefunction.